Imagem:Cauer response.png

Origem: Wikipédia, a enciclopédia livre.

Imagem
Histórico
Ligações

Cauer_response.png‎ (33KB, tipo MIME: image/png)

Este arquivo foi carregado no Wikimedia Commons, um acervo de conteúdo livre da Fundação Wikimedia. Veja a página descritiva da imagem para informações sobre a licença.

[edit] Summary

Cauer filter response; the amount of passband ripple is exaggerated to make it easy to see

[edit] Instructions

See Wikipedia graph-making tips.

This image, as well as the following text, is derived from Image:Butterworth_response.png.

Generated in gnuplot with the following script (save as ellip.plt and then open in gnuplot):

set samples 2001
set terminal postscript enhanced landscape color lw 2 "Times-Roman" 20
set output "ellip.ps"

# 4-pole elliptic filter
H(s) = (s*s+2.893562487**2)*(s*s+1.384621199**2)/((s*s-2*(-.054235367)*s+.93542)*(s*s-2*(-.21417)*s+.2709))/93.26
G(w) = abs(H(w * {0,1}))
dB(x) = 20 * log10(abs(x))

# Gridlines
set grid

# Set x axis to logarithmic scale
set logscale x 10

# Set range of x and y axes
set xrange [0.01:100]
set yrange [-60:10]

# Create x-axis tic marks once per decade (every multiple of 10)
set xtics 10

# Use 10 x-axis minor divisions per major division
set mxtics 10

# Axis labels
set xlabel "Angular frequency (rad/s)"
set ylabel "Gain (dB)"

# No need for a key
set nokey #0.1,-25

# Frequency response's line plotting style
set style line 1 lt 1 lw 2

# Draw a separator between passband and stopband and label them
set style line 2 lt 2 lw 1 
set style arrow 2 nohead ls 2
set arrow 3 from 1,-60 to 1,10 as 2

# Label coordinates are relative to the graph window, not to the function, centered at the 1/4 and 3/4 width points
set label 1 "Passband" at graph 0.25, graph 0.1 c
set label 2 "Stopband" at graph 0.85, graph 0.1 c

# Asymptote lines and slope lines are the same "arrow" style
set style line 3 lt 3 lw 1
set style arrow 3 nohead ls 3

# -3 dB arrow style and arrow
set style line 4 lt 4 lw 1
set style arrow 4 head filled size screen 0.02,15,45 ls 4
set arrow 4 from 2,3 to 1,0 as 4

# "Cutoff frequency" label uses same coordinates as the function
set label 3 "Cutoff frequency" at 2,4 l

# Plot the filter response
plot dB(G(x)) ls 1  title "4th-order response"

Then I opened the ellip.ps file in a text editor to edit the line colors and linestyles, as per this description. This avoids needing to open in proprietary software, and really isn't that difficult (especially if you don't know the commands in the proprietary software either). ;-) Identify the lines easily by their color (the arrow is currently magenta and I want it to be black. Ah, there is the entry with 1 0 1, red + blue = magenta) or by using the gnuplot linestyle−1. (For instance, gnuplot's linestyle 3 corresponds to the ps file's /LT2.) Then you can edit the colors and dashes by hand. I changed the original:

/LT0 { PL [] 1 0 0 DL } def
/LT1 { PL [4 dl 2 dl] 0 1 0 DL } def
/LT2 { PL [2 dl 3 dl] 0 0 1 DL } def
/LT3 { PL [1 dl 1.5 dl] 1 0 1 DL } def

into this:

/LT0 { PL [] 0 0 1 DL } def
/LT1 { PL [4 dl 2 dl] 0.5 0.5 0.5 DL } def
/LT2 { PL [6 dl 3 dl] 0.3 0.3 1 DL } def
/LT3 { PL [] 0 0 0 DL } def

Then I displayed the ellip.ps using the Mac Preview App, and used SnapNDrag to save the useful part of the image to a file.

Created by Pfalstad from Image:Butterworth_response.png.

[edit] Licensing

I, the author of this work, hereby publish it under the following licenses:

Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation License, Version 1.2 or any later version published by the Free Software Foundation; with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts. A copy of the license is included in the section entitled "GNU Free Documentation License".