Resim:Alpha Centauri relative sizes.png

A comparison of the sizes and colors of the stars in the Alpha Centauri system with the Sun.

David Benbennick made this image on January 29, 2005 with the following Metapost program as stars.mp:

verbatimtex
\font\foo=cmss9 at 10pt
\foo
etex

sunrad=0.3in;
alpharad = 1.227*sunrad;
betarad = 0.865*sunrad;
proximarad = 0.145*sunrad;
gap = 0.8*sunrad;

pair sunpos, alphapos, betapos, proximapos;
sunpos = (0 + gap + sunrad, 1.9*sunrad);
alphapos = sunpos + (sunrad + gap + alpharad, 0);
betapos = alphapos + (alpharad + gap + betarad, 0);
proximapos = betapos + (betarad + gap + proximarad, 0);

beginfig(1);

  fill unitsquare xscaled ((xpart proximapos) + proximarad + gap)
    yscaled (2 * (ypart sunpos));

  fill fullcircle scaled (2*sunrad) shifted sunpos
    withcolor (1,0.960,0.949);   % Color is fff1ed
  label.bot(btex Sun etex, sunpos - (0, sunrad)) withcolor white;

  fill fullcircle scaled (2*alpharad)
    shifted alphapos
    withcolor (1,0.960,0.949);
  label.bot(btex $\alpha$ Centauri A etex, alphapos - (0, alpharad))
    withcolor white;

  fill fullcircle scaled (2*betarad)
    shifted betapos
    withcolor (1,0.878,0.737);  % ffe0bc
  label.bot(btex $\alpha$ Centauri B etex, betapos - (0, betarad))
    withcolor white;

  fill fullcircle scaled (2*proximarad)
    shifted proximapos
    withcolor (1,0.752,0.411);  % ffcc6f
  label.bot(btex Proxima etex, proximapos - (0, proximarad))
    withcolor white;

endfig;
end;

And I had the following TeX file as stars.tex:

%&latex
\documentclass[10pt]{article}
 \usepackage{graphicx}
 \pagestyle{empty}
\begin{document}
 \includegraphics{stars.1}
\end{document}

Then I ran

mpost stars
tex stars
dvips -mode ljfzzz -D 1200 stars -o
convert -density 1200 -chop 99999x99999+6249+3463 -chop 2479x2095 stars.ps stars.png
pngcrush -reduce -brute -l 9 stars.png stars.crush.png

stars.crush.png was the final output file.

(Apparently it's non-trivial to get dvips to use a given resolution. I would have preferred to use 1600 dpi, but dvips didn't already have a "printer" at that resolution. ljfzzz, at 1200, was the best I could find.)

I, the author of this work, hereby publish it under the following licenses: Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation License, Version 1.2 or any later version published by the Free Software Foundation; with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts. A copy of the license is included in the section entitled "GNU Free Documentation License". العربية | Česky | Deutsch | English | Español | Français | Italiano | 日本語 | 한국어 | Nederlands | Polski | Português | Slovenčina | Svenska | עברית +/- This file is licensed under Creative Commons Attribution ShareAlike 2.0 License You may select the license of your choice.

[edit] References

• I took the star colors from [1], which indicates they're only approximate. Apparently there are inherent difficulties in representing a star's color on a computer monitor.
• I took the star radii from [2].